Priest Macros

General Macros

General macros and templates that you can use to enhance your spellcasting abilities.

Universal Macros

Healing Macros

DPS Macros

Elvenbane's Personal BFA Macros

These are my personal macros that I use for each spec.

General Macros

Heart of Azeroth Essence Macro

Alt: Self Cast
Mouseover: Cast on Mouseover
Reticle: Cast at Cursor (while in combat)
Default casting behavior. This condition also serves to generate the correct tooltip.

#showtooltip
/cast [mod:alt,@player] [@mouseover,exists,nodead] [@cursor,combat] [] Heart Essence

Covenant Macro

Unfortunately this macro will only function as-is while doing the campaign. Once you select your covenant you'll need to replace the placeholder spells with the specific spells granted by the covenant (no idea why Blizz has made it work this way but they have).

Signature Ability (mod), Covenant Ability

#showtooltip
/cast [mod,@mouseover,exists,nodead] [mod,@cursor,combat] [mod] Signature Ability; [@mouseover,exists,nodead] [@cursor,combat] [] Covenant Ability

CC Macros

Clear Focus (shift), Set/Shackle Focus (alt), Shackle Target

#showtooltip
/focus [mod:alt,@focus,dead] [mod:alt,@focus,noexists]
/clearfocus [@focus,dead] [mod:alt,@focus,noexists] [mod:shift]
/cast [mod:alt,@focus,exists] [] Shackle Undead

Clear Focus (shift), Set/Mind Control Focus (alt), Mind Control Target

#showtooltip
/focus [mod:alt,@focus,dead] [mod:alt,@focus,noexists]
/clearfocus [@focus,dead] [mod:alt,@focus,noexists] [mod:shift]
/cast [mod:alt,@focus,exists] [] Mind Control

Dispel Macro

I use BindPad for this and have it bound to the key to the left of 1: `

Mass Dispel (alt), Dispel Magic (harm), Purify Disease (help, shadow), Purify (help)

#showtooltip
/cast [mod:alt] !Mass Dispel; [spec:3,@mouseover,help,nodead] Purify Disease; [@mouseover,help,nodead] Purify; [@mouseover,harm,nodead] [harm] Dispel Magic; [spec:3] Purify Disease; Purify

Angelic Feather Macro

7.1.5 introduced the [@cursor] and [@player] conditions for reticle targeted spells. The following macro casts Angelic Feather at your feet.

#showtooltip
/cast [@player] Angelic Feather

Dispersion Cast/Cancel Macro

Click to cast, Right click to Cancel - You can replace [btn:2] with any other conditional you'd rather use.

#showtooltip
/cancelaura [btn:2] Dispersion
/cast Dispersion

Spirit of Redemption Cancel Macro

For whatever reason, Spirit of Redemption is no longer considered a buff and is now a form. You can add any of the usual macro conditions to it if you'd like.

/cancelform

Reticle Spell Macro

This is a basic macro for reticle spells such as Shadow Crash and Holy Word: Sanctify

Alt: Cast at Player
Combat: Cast at Cursor
Default casting behavior. This condition also serves to generate the correct tooltip.

#showtooltip
/cast [mod:alt,player] [@cursor,combat] [] SPELL

Nochanneling Macro

nochanneling returns false while another spell is channeling. This allows you to prevent spells from casting and is often used to prevent Penance clipping.

Single condition:

#showtooltip SPELL
/cast [nochanneling:CHANNELING SPELL] SPELL

Multiple conditions:

#showtooltip
/stopmacro [channeling:CHANNELING SPELL]
/cast [mod:alt,@player] [@mouseover,help,nodead] [help] [@targettarget,help,nodead] [] SPELL

Using the /stopmacro variant prevents you from needing to add nochanneling to each condition within your macro, vastly simplifying the construction and cutting down on the number of characters required. It also makes it so you don't need to specify the #showtooltip as the /cast will do it for you like usual. I personally prefer this method even for single condition macros.

Stopcasting Macro

This macro will cancel any queued spells and interrupt your current cast before casting a spell. Note: this functionality is automatically baked into all interrupts. Also, this is really only useful for cancelling spells with a cast time > 1 GCD or if you're cancelling so you can cast a spell that's off the GCD.

#showtooltip
/cqs
/stopcasting
/cast SPELL

Healing Macros

Base Healing Macro

This is the base macro that all my healing macros are derived from.

Alt: Self Cast
Mouseover Friend: Cast on Mouseover
Target Friend: Cast on Target
Target Enemy Targeting Friend: Cast on Enemy's Target
Default casting behavior. This condition also serves to generate the correct tooltip.

#showtooltip
/cast [mod:alt,@player] [@mouseover,help,nodead] [help] [@targettarget,help,nodead] [] SPELL

Basic Help/Harm Macro

This will cast one spell when mousing over or targeting a friend and another when mousing over or targeting an enemy.

#showtooltip
/cast [@mouseover,help,nodead] HELP_SPELL; [@mouseover,harm,nodead] [harm] HARM_SPELL; HELP_SPELL

Penance Macros

This is a collection of Penance macros that give you more control of whether or not you're casting on a helpful or harmful target.

Self (alt) > Mouseover > Target

#showtooltip
/cast [mod:alt,@player] [@mouseover,exists,nodead] [] Penance

Self (alt) > Mouseover Help (mod) > Mouseover Harm > Target

#showtooltip
/cast [mod:alt,@player] [mod,@mouseover,help,nodead] [@mouseover,harm,nodead] [] Penance

Mouseover Harm > Target Harm

#showtooltip [@mouseover,harm,nodead] [] Penance
/cast [@mouseover,harm,nodead] [harm] Penance

Self (alt) > Mouseover Help > Target Help

#showtooltip [mod:alt,@player] [@mouseover,help,nodead] [] Penance
/cast [mod:alt,@player] [@mouseover,help,nodead] [help] Penance

DPS Macros

DPS Mouseover Macro

This is a basic mouseover macro for offensive spells such as Shadow Word: Pain, Vampiric Touch, and Void Eruption (Void Bolt)

Mouseover Enemy: Cast on Mouseover
Default casting behavior. This condition also serves to generate the correct tooltip.

#showtooltip
/cast [@mouseover,harm,nodead] [] SPELL

Offensive Macro for Healers

This macro is primarily for healers who want to play Disc but want to play it like a traditional healer. Basically allows you to dps while having fiendly players targeted or moused over.

Mouseover Enemy: Cast on Mouseover
Target Enemy: Cast on Target
Mouseover Friend Targeting Enemy: Cast on Friend's Target
Target Friend Targeting Enemy: Cast on Friend's Target
Default casting behavior. This condition also serves to generate the correct tooltip.

#showtooltip
/cast [@mouseover,harm,nodead] [harm] [@mouseovertarget,harm,nodead] [@targettarget,harm,nodead] [] SPELL

Searing Nightmare

This macro will cast Searing Nightmare while channeling Mind Sear and being talented into the spell, otherwise it will cast Shadow Word: Pain

With SWP Mouseover Support

#showtooltip
/cast [channeling:Mind Sear,talent:3/3] Searing Nightmare; [@mouseover,harm,nodead] [] Shadow Word: Pain

Without

#showtooltip
/cast [channeling:Mind Sear,talent:3/3] Searing Nightmare; Shadow Word: Pain

Shadow

** Important **

Before using these macros make sure you unbind the Action Page 1 - 6 keys in your key bindings. If you don't, pressing any of the shift modified macros will cause you to change action page instead of casting the appropriate spell.

I've included the keys I have them bound to but you can use whatever.

#1 - Leap of Faith (shift+alt), Psychic Scream (shift), Vampiric Touch (alt), Shadow Word: Pain

#showtooltip
/cast [mod:shiftalt,@mouseover,help,nodead] [mod:shiftalt] Leap of Faith; [mod:shift] Psychic Scream; [mod:alt,@mouseover,harm,nodead] [mod:alt] Vampiric Touch; [@mouseover,harm,nodead] [] Shadow Word: Pain

#2 - Vampiric Embrace (shift+alt), Searing Nightmare (shift), Mind Sear (alt), Mind Flay

#showtooltip
/cast [mod:shiftalt] Vampiric Embrace; [mod:shift,talent:3/3] Searing Nightmare; [mod:alt] Mind Sear; Mind Flay

#3 - Shadow Crash (shift+alt), Power Word: Shield (shift), Devouring Plague (alt), Mind Blast

#showtooltip
/cast [mod:shiftalt,talent:5/3,@cursor,combat] [mod:shiftalt,talent:5/3] Shadow Crash; [mod:shift,@mouseover,help] [mod:shift,@player] Power Word: Shield; [mod:alt,@mouseover,harm,nodead] [mod:alt] Devouring Plague; Mind Blast

#4 - Surrender to Madness (shift+alt), Shadowfiend (shift), Shadow Word: Death (alt), Void Eruption/Void Bolt

#showtooltip
/cast [mod:shiftalt,talent:7/3,@mouseover,harm,nodead] [mod:shiftalt,talent:7/3] Surrender to Madness; [mod:shift] Shadowfiend; [mod:alt,@mouseover,harm,nodead] [mod:alt] Shadow Word: Death; [@mouseover,harm,nodead] [] Void Eruption

#5 - Psychich Horror (alt), Silence (shift), Fade

#showtooltip
/cast [mod:alt,talent:4/3] Psychic Horror; [mod:shift] Silence; Fade

DPS Potion (ctrl), Dispersion (shift), Power Infusion (alt), Damnation/Void Torrent (in form), Shadowform

#showtooltip
/cancelaura [mod:shift]Dispersion
/use [mod:ctrl] Potion of Deathly Fixation; [mod:shift] Dispersion; [mod:alt] Power Infusion; [form,talent:6/1,@mouseover,harm,nodead] [form,talent:6/1] Damnation; [form,talent:6/3] Void Torrent; !Shadowform

Holy

** Important **

Before using these macros make sure you unbind the Action Page 1 - 6 keys in your key bindings. If you don't, pressing any of the shift modified macros will cause you to change action page instead of casting the appropriate spell.

I've included the keys I have them bound to but you can use whatever.

Note: alt click will cast the unmodified spell on yourself. ie Alt-1 = PoM on self

#1 - Leap of Faith (shift+alt), Divine Star/Halo (shift), Prayer of Mending

#showtooltip
/cast [mod:shiftalt,@mouseover,help] [mod:shiftalt] Leap of Faith; [mod:shift,talent:6/2] Divine Star; [mod:shift,talent:6/3] Halo; [mod:alt,@player] [@mouseover,help] [help] [@targettarget,help] [] Prayer of Mending

#2 - Symbol of Hope (shift+alt), Guardian Spirit (shift), Flash Heal

#showtooltip
/cast [mod:shiftalt] Symbol of Hope; [mod:shift,@mouseover,help] [mod:shift] Guardian Spirit; [mod:alt,@player] [@mouseover,help] [help] [@targettarget,help] [] Flash Heal

#3 - Holy Word: Salvation (shift+alt), Holy Word: Sanctify (shift), Holy Word: Serenity

#showtooltip
/cast [mod:shiftalt,talent:7/3] Holy Word: Salvation; [mod:shift,combat,@cursor] [mod:shift] Holy Word: Sanctify; [mod:alt,@player] [@mouseover,help] [help] [@targettarget,help] [] Holy Word: Serenity

#4 - Binding Heal/Circle of Healing (nomod), Divine Hymn

#showtooltip 
/cast [nomod,talent:5/2,@mouseover,help,nodead] [nomod,talent:5/2] Binding Heal; [nomod,talent:5/3,@mouseover,help,nodead] [nomod,talent:5/3] Circle of Healing; Divine Hymn /stopspelltarget

#5 - Heal (shift), Renew

#showtooltip
/cast [mod:shift,@mouseover,help,nodead] [mod:shift,help] [mod:shift,@targettarget,help,nodead] [mod:shift] Heal; [mod:alt,@player] [@mouseover,help] [help] [@targettarget,help] [] Renew

Num- (Number 4 on my Naga) - Desperate Prayer (ctrl), Angelic Feather [@player] (shift), Apotheosis/Holy Word: Salvation (alt), Prayer of Healing

#showtooltip
/cast [mod:ctrl] Desperate Prayer; [mod:shift,talent:2/3,@player] Angelic Feather; [mod:alt,talent:7/2] Apotheosis; [mod:alt,talent:7/3] Holy Word: Salvation; [@mouseover,exists] [] Prayer of Healing

Discipline

** Important **

Before using these macros make sure you unbind the Action Page 1 - 6 keys in your key bindings. If you don't, pressing any of the shift modified macros will cause you to change action page instead of casting the appropriate spell.

I've included the keys I have them bound to but you can use whatever.

Note: alt click will cast the unmodified spell on yourself. ie Alt-1 = Plea on self

#1 - Leap of Faith (shift+alt), DStar/Halo (shift), Penance

#showtooltip
/cast [mod:shiftalt,@mouseover,help] [mod:shiftalt] Leap of Faith; [mod:shift,talent:6/2] Divine Star; [mod:shift,talent:6/3] Halo; [mod:alt,@player] [@mouseover,exists,nodead] [] Penance

#2 - Rapture (shift+alt), Pain Suppression (shift), Power Word: Shield

#showtooltip
/cast [mod:shiftalt,@mouseover,help][mod:shiftalt] Rapture;[mod:shift,@mouseover,help][mod:shift,help][mod:shift,@targettarget,help][mod:shift] Pain Suppression;[mod:alt,@player][@mouseover,help][help][@targettarget,help][] Power Word: Shield

#3 - Mind Sear (shift+alt), Schism (shift), Mind Blast (alt), Shadow Word: Pain

#showtooltip
/stopmacro [channeling:Penance]
/cast [mod:shiftalt] Mind Sear; [mod:shift,talent:1/3,@mouseover,harm,nodead] [mod:shift,talent:1/3] Schism; [mod:alt,@mouseover,harm,nodead] [mod:alt] Mind Blast; [@mouseover,harm,nodead] [] Shadow Word: Pain

#4 - Power Word: Solace (shift), Shadowfiend (mod), Smite

#showtooltip
/cast [mod:shift,talent:3/3,@mouseover,harm,nodead] [mod:shift,talent:3/3] Power Word: Solace; [mod,harm] [mod,@targettarget,harm] [mod] Shadowfiend; [@mouseover,harm,nodead] [] Smite

#5 - Shadow Covenant (shift), Power Word: Barrier (mod), Shadow Mend

#showtooltip
/cast [mod:shift,talent:5/3,@mouseover,help] [mod:shift,talent:5/3] Shadow Covenant; [mod] Power Word: Barrier; [@mouseover,help] [help] [@targettarget,help] [] Shadow Mend

Num- (Number 4 on my Naga) - Evangelism (ctrl), Angelic Feather [@player] (shift), Power Word: Radiance

#showtooltip
/cast [mod:ctrl,talent:7/3] Evangelism; [mod:shift,talent:2/3,@player] Angelic Feather; [@mouseover,help] [] Power Word: Radiance